One language for apps,
services, and interfaces.

module rocket {
	use std.units::*

	// Contracts: checked when the function starts and when it returns.
	def burnTime(fuel Mass, rate MassFlow) !Time {
		expects {
			assert rate > 0 onerror fail "engine off"
		}
		let t = fuel / rate
		return t
		provides {
			assert t < 10(min) onerror fail "burn too long: {t.str(min)}"
		}
	}

	// Compiled for the GPU; runs on the CPU when there is none.
	cuda def cool(temps float64[], by float64) !none {
		int i = blockIdx.x * blockDim.x + threadIdx.x;
		if (i < temps_len) temps[i] -= by;
	}

	async def weather() string {
		use std.net.http
		let reply = http.get("https://wttr.in/Cape+Canaveral?format=3") onerror return "no go"
		return reply.text() onerror recover "no go"
	}

	async def range() string {
		return "go"
	}
}

application Launch {
	use (
		std.units::*
		rocket
	)

	let fuel Mass = 0

	def load(m Mass) {
		begin { fuel += m }
		rollback { fuel -= m }
	}

	// When anything inside fails, every rollback runs.
	def fuelUp(m Mass) !none {
		transaction {
			load(m)
			let t = try rocket.burnTime(fuel, 2.5(t/s))
			println("burn for {t.str(s)}")
		} onerror (err error) {
			println("scrubbed: {err.message}, fuel back to {fuel.str(t)}")
			recover none
		}
		return none
	}

	def new(args string[]) int {
		fuelUp(2000(t)) onerror return 1
		fuelUp(400(t)) onerror return 1

		// Both checks run at once; the first answer wins.
		let status = await (rocket.weather() || rocket.range())
		println("status: {status}")

		// All four engines compared in one SIMD instruction.
		let temps = float64[910.0, 870.0, 1020.0, 880.0]
		let v vec4<float64>
		let hot = v.load(temps, 0).gt(v.splat(1000.0))
		if hot.any() {
			rocket.cool(temps, 50.0) onerror recover none
		}

		// One task per engine, spread across cores, reporting on a channel.
		let telemetry channel<string> = new(size = 4)
		forall let (i, t) in temps {
			telemetry <- "engine {i}: {int(t)} K"
		}
		telemetry.close()
		for let line in telemetry {
			println(line)
		}
		return 0
	}
}